Berechnung von Radandrehspuren

Die Parametrische Darstellung der Trajektorie eines Punktes auf der Radaußenflanke lautet

[math]\displaystyle{ x = (1 - 1/z) r_0 \phi + r sin \phi }[/math]

[math]\displaystyle{ y = r cos \phi }[/math]

Die Herleitung findet sich etwa in "Die Aufklärung des Kfz-Versicherungsbetrugs".
Es sind

• r: der Radius des Betrachteten Punktes
• r₀: der Außenradius des Rades
• φ: der Drehwinkel
• z: das Geschwindikeitsverhältnis der Fahrzeuge v₁ / v₂

Der Nullpunkt liegt bei obiger Formel im Radzentrum; legt man ihn auf die Fahrbahnoberfläche, ist bei der y-Koordinate r₀ zu addieren. Das unten gelistete AutoSketch-Makro zeichnet Polylinien mit den Bewegungsbahnen der Punkte zischen Radinnenradius und Radaußenradius, ähnlich wie dies im entsprechenden Modul von PC-Crash 8.0 geschieht. Die Makrosprache von AutoSketch 2.1 ähnelt BASIC, sodass das Makro in ähnlicher Form auch in anderen CAD-Umgebungen schnell umgesetzt werden kann.

Um das Makro in AutoSketch zu verwenden kopiert man die Befehle in einen Editor und speichert es in einer Datei mit der Enden MCR (macro). Dann kann es im Menü "Einstellungen" mit der entsprechenden Schaltfläche abgespielt werden. Im Bild sind die entscheidenden Punkte beim Ausführen des Makros markiert:

Vor dem Ausführen des Makros muss man zunächst den Nullpunkt (Ursprung) der gesamten Zeichnung auf den Radmittelpunkt legen. (= Oben links of den Schnittpunkt der Lineale kliecken und dann den Radmittelpunkt bezeichnen.)

Anschließend hängt das Fadenkreuz (der Cursor) an einem "Gummiband" an diesem Ursprung; und man klickt "ganz oben" auf den Radinnenkreis. Danach macht man nochmals dasselbe für den Radaußenkreis.

Danach erscheint das Dialogfeld "Einfügebasis":

Wie bei allen Makros der Venus Toolbox zeigt der Vorgabewert -1 für Y an, dass für Y keine Eingabe erwartet wird. Für den Wert X gibt man das Geschwindigkeitsverhältnis z aus obiger Formel ein. Das Makrozeichnet dann die Radandrehspuren:

' AutoSketch 2.1 Makro zum zeichnen von Radandrehspuren
' Der Nullpunkt der Zeichnung muss zuvor ins Radzentrum gelegt werden
'
' Fehlerschranke
eps = 0.0001
' Winkel-Inkrement
dphi = 0.1
' Endwinkel der Simulation in Radiant
Ende = 4 * /pi
' Umrechnungsfaktor in Radiant
deg = 57.52
' Anzahl der Streifen
Strips=5
' Richtung: -1 = von rechts nach links     
dir = -1.0
' Wert wird später restauriert
OldPD = /PICKDELTA 
'
' Radius des Randinnenrands
DrawLine   
Point 0,0
UserInput
rmin = /ly
Undo
'
' Radius des Radaußenrands
DrawLine
Point 0,0
UserInput
r0 = /ly
Undo
'
' Angabe des Geschwindigkeitsverhältnisses
Set INSBASEX 0
Set INSBASEY -1
SetPartBase
UserInput
z = /INSBASEX
'
dr = (r0-rmin) / (Strips-1)
r = rmin
' Auswahlbox auf Null setzen, damit die Polylinien nicht
' versehentlich beendet werden
Set PICKDELTA 0
Repeat
  phi = 0
  DrawPolyLine
  Repeat
    x = dir * (r0*(1-1/z) * phi + r*sin(deg*phi))
    y = r*cos(deg*phi)
    Point x,y
    phi = phi + dphi
  until phi > ende
  Point /lpoint
  r = r + dr
until r > r0 + eps
'
' Wert restaurieren
Set PICKDELTA OldPD