ImageMagick

Grundsätzliches

ImageMagick ist ein kostenloses, skriptgesteuertes Programm zur Bildbearbeitung, das auf vielen Internet-Servern eingesetzt wird. Es lässt sich jedoch auf normalen Windows-Rechnern installieren und auch in der Unfallrekonstruktion sinnvoll einsetzen. Das Programm wird in einer DOS-Box aufgerufen und über die Kommandozeilenparameter gesteuert und offenbart seine Stärken erst bei der standardisierten (Stapel-) Verarbeitung von Bildern, speziell Fotos: Gerade weil die Bedienung so kryptisch ist, garantieren einmal erstellte Skripte, dass die entsprechende Operation stets in gleicher Weise durchgeführt wird. Anwendungsfälle in der Unfallrekonstruktion sind z.B.:

• Ändern von Größe + JPEG-Kompression von Fotos
• Umwandeln von (auch geschützten) PDF-Seiten in JPEGs
• Automatische Belichtungskorrektur
• Erstellen von Indexprints für Fotoverzeichnisse

Eine einfache DOS-Stapelverarbeitungsdatei zum "Kleinrechnen" aller Fotos in einem Verzeichnis sieht etwa folgendermaßen aus:

MD _klein
FOR %%v IN (*.JPG) DO ^
convert "%%v" -resize 928x928 -quality 80%% -density 150x150 "_klein\s_~nxv"

Weitere Anwendungsbeispiele zu ImageMagick finden sich in Hugemann: Unfallrekonstruktion im Kapitel "Bild- und Videobearbeitung". Auf der Website zum Buch finden registrierte Benutzer etliche Beispielskripte samt Erläuterungen.

Installation

Fertige Installationsdateien (auch) für Windows finden sich unter http://www.imagemagick.org/script/binary-releases.php. Dort gibt es eine Vielzahl unterschiedlicher Versionen, jedoch steht die jeweils empfohlene Installationsdatei stets ganz oben für sich allein. Derzeit (Ende 2015) nennt sie sich ImageMagick-6.9.2-8-Q16-x64-dll.exe:

• 6.9.2-8 = Versionsnummer
• Q16 = Farbtiefe 16 bit
• x64 = 64-bit-Version
• dll = die Hilfsbibliotheken (DLLs) werden zur Laufzeit eingebunden.

Der Standard-Installationspfad beinhaltet (wie bei vielen Unix-Programmen üblich) die Versionsnummer des Programms, lautet bei der oben zitierten Version also C:\Programme\ImageMagick-6.9.2-8. Man kann auf diese Weise mehrere Programmversionen parallel betreiben, was in der Regel jedoch nicht sinnvoll ist. Wenn man den Installationspfad auf C:\Programme\ImageMagick verkürzt, kann man anschließend aktuelle Versionen in eben diesem Verzeichnis schlicht "darüber" installieren, ohne die Vorgängerversion vorab zu de-installieren.

Aus historischen Gründen erwarten die Skripts von Wolfgang Hugemann, dass das wichtigste Kommandozeilenprogramm von ImageMagick, convert.exe in IMconv.exe umbenannt wurde. (Convert ist ein Windows-Systembefehlt, der FAT-Laufwerke in NTFS umformatiert.) Dieser Schritt ist nach der Installation im Windows-Explorer manuell vorzunehmen, sofern man diese Skripte verwendet. Anschließend sicherheitshalber eine DOS-Box öffnen (Start > Ausführen > cmd) und IMconv eingeben; dann sollte ImageMagick einen Text zurückmelden.

Skript zum Kleinrechnen von Fotos im Stapelbetrieb

Das folgende Skript (Stapelverarbeitungsdatei, Batchdatei) rechnet ausgewählte oder sämtliche Fotos in einem Verzeichnis auf feste maximale Größe und feste JPEG-Qualität um. Beide Parameter werden zu Beginn des Skripts vorgegeben, hier mit 2.400 Pixeln (größere Abmessung) und 50%. Sind die Abmessungen des Fotos kleiner, so wird nur die JPEG-Qualität geändert. Die von der Kamera typischerweise eingebetteten Thumbnails werden gelöscht, um den Datenballast zu reduzieren. Die bearbeiteten Fotos werden in einem Unterverzeichnis festen Namens (Vorgabe: _klein) gespeichert.

Das Skript setzt voraus, dass dem Laufwerk ein Laufwerksbuchstabe zugeordnet ist (sonst Fehlermeldung). Das ImageMagick-Programm Convert.exe ist für das Skript in IMconv.exe umbenannt worden. Das muss aber nicht unbedingt sein. Das Programm jhead speichert man am besten im gleichen Verzeichnis wie ImageMagick.

Das Skript wird am besten zentral auf dem Server abgelegt, in einer Datei, die sich z.B. "Fotolein.bat", "Foto_klein.cmd" oder sonstwie nennt. (Hauptsache, die Endung lautet .bat oder .cmd.) Auf den Clients dann Verknüpfungen zu diesem Skript im SendTo-Ordner anlegen.

Wird nur eine Datei an das Skript geschickt, so werden alle Fotos im Verzeichnis kleingerechnet, ansonsten nur die ausgewählten.

::=============================================================
:: Fotos für den Messlattenserver aufbereiten
::  Benötigte Programme:
::    ImageMagick (www.imagemagick.org)
::    jhead (www.sentex.net/~mwandel/jhead)
::           zum Entfernen des Thumbnails
::
:: Version 1.0 von 2013-01-29:
::
:: (c) Wolfgang Hugemann, IB MuH
::=============================================================
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
:: Vorgaben
:: Name des IM-Programms 'convert'
SET IM=IMconv
:: JPEG-Qualitaet der kleingerechneten Fotos
SET quality=50
:: Groessere der beiden Abmessungen des kleingerechneten Fotos
SET size=2400
::
:: Name des Unterverzeichnisses, in dem die kleingerechnten Bilder gespeichert werden
SET dir=_klein
:: Ausgabeanweisung
:: Testen, ob ImageMagick instaliert ist
%IM% -version 2>nul
IF NOT %errorlevel%==0 GOTO NoMagick:

:: Netzwerklaufwerk ohne Laufwerksbuchstaben können nicht behandelt werden
IF (%~d1) == (\\) Goto Error:
:: Wechsel auf das aktuelle Laufwerk
%~d1
:: Wechsel in das Verzeichnis oder das Verzeichnis der Datei
IF EXIST %1\* ( CD %1 ) ELSE CD %~p1
:: Unterverzeichnis erstellen
MD %dir% 2>nul:
::
:: Wenn nur eine Datei uebergeben wurde => alle bearbeiten
IF '%2'=='' (
SET PATTERN=*.jpg
) ELSE (
SET PATTERN=%*
)

FOR %%v IN (%PATTERN%) DO (
ECHO %%~nxv
%IM% "%%~v" -resize %SIZE%x%SIZE%">" -quality %QUALITY% "%DIR%\%%~nxv"
jhead -dt "%DIR%\%%~nxv"
)
GOTO :EOF

:ERROR
ECHO Angegebener Pfadname:
ECHO %1
ECHO Bitte nur Netzwerklaufwerke benutzen, die auch
ECHO einen Laufwerksbuchstaben haben (z.B. W:).
PAUSE
GOTO :EOF

:NoMagick
ECHO ImageMagick (%IM%.exe) nicht gefunden.
ECHO Haben Sie vergessen convert.exe umzubenennen?
PAUSE

Weitere Infos

• http://www.imagemagick.org
• http://www.imagemagick.org/Usage/windows: Nutzung von ImageMagick unter Windows (von Wolfgang Hugemann in Englisch verfasst)
• http://de.wikipedia.org/wiki/ImageMagick (eher dürftige Information)